//+------------------------------------------------------------------+
//|                                                Cronex Taichi.mq4 |
//|                                                                  |
//| original indicator developed by cronex                           |
//| improvments and cleanup made by newdigital and mladen            |
//+------------------------------------------------------------------+
#property  copyright "www.forex-tsd.com"
#property  link      "www.forex-tsd.com"

#property  indicator_chart_window
#property  indicator_buffers 6
#property  indicator_color1  DeepSkyBlue
#property  indicator_color2  Red
#property  indicator_color3  LimeGreen
#property  indicator_color4  Orange
#property  indicator_color5  DimGray
#property  indicator_color6  DimGray
#property  indicator_width1  2
#property  indicator_width4  2
#property  indicator_style5  STYLE_DOT
#property  indicator_style6  STYLE_DOT

//
//
//
//
//

extern string TimeFrame   = "Current time frame";
extern int    Tenkan      =  9;
extern int    Kijun       = 26;
extern int    Senkou      = 52;
extern bool   Interpolate = true;

//
//
//
//
//

double     TaichiBuffer[];
double     TaichiForBuffer[];
double     SignalBuffer[];
double     SSignalBuffer[];
double     FlatBuffer1[];
double     FlatBuffer2[];

//
//
//
//
//

string indicatorFileName;
bool   calculateValue;
bool   returnBars;
int    timeFrame;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorDigits(Digits+1);
      SetIndexBuffer(0,TaichiBuffer);    SetIndexLabel(0,"Taichi");
      SetIndexBuffer(1,SignalBuffer);    SetIndexLabel(1,"Signal");
      SetIndexBuffer(2,SSignalBuffer);   SetIndexLabel(2,"SSignal");
      SetIndexBuffer(3,TaichiForBuffer); SetIndexLabel(3,"TaichiFor"); 
      SetIndexBuffer(4,FlatBuffer1);     SetIndexLabel(4,"FlatUp");    SetIndexStyle(4,DRAW_HISTOGRAM);
      SetIndexBuffer(5,FlatBuffer2);     SetIndexLabel(5,"FlatDn");    SetIndexStyle(5,DRAW_HISTOGRAM);

   //
   //
   //
   //
   //
   
   indicatorFileName = WindowExpertName();
   timeFrame         = stringToTimeFrame(TimeFrame);
   returnBars        = (TimeFrame=="returnBars");    if (returnBars) return(0);
   calculateValue    = (TimeFrame=="CalculateValue"); 
            if (!calculateValue) SetIndexShift(3,Kijun*timeFrame/Period());

   //
   //
   //
   //
   //
         
   IndicatorShortName(timeFrameToString(timeFrame)+" Cronex Taichi");
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars = IndicatorCounted();
   int limit,i;
   
   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;   
           limit=MathMin(Bars-counted_bars,Bars-1);
           if (returnBars) { TaichiBuffer[0] = MathMin(limit+Kijun,Bars-1); return(0); }

   //
   //
   //
   //
   //
   //
   
   if (calculateValue || timeFrame == Period())
   {
      for(i=-Kijun; i<limit; i++)
      {
         double TenkanSen   = iIchimoku(NULL,0,Tenkan,Kijun,Senkou,MODE_TENKANSEN,i);
         double KijunSen    = iIchimoku(NULL,0,Tenkan,Kijun,Senkou,MODE_KIJUNSEN,i);
         double SenkouSpanA = iIchimoku(NULL,0,Tenkan,Kijun,Senkou,MODE_SENKOUSPANA,i);
         double SenkouSpanB = iIchimoku(NULL,0,Tenkan,Kijun,Senkou,MODE_SENKOUSPANB,i);
         double ChinkouSpan = iIchimoku(NULL,0,Tenkan,Kijun,Senkou,MODE_CHINKOUSPAN,i);      

         TaichiForBuffer[i+Kijun] = (SenkouSpanA+SenkouSpanB)/2.0;
            if (i>=0)
               TaichiBuffer[i] = (TenkanSen+KijunSen+SenkouSpanA+SenkouSpanB)/4.0;
      }
      
      //
      //
      //
      //
      //
      
      for(i=0; i<limit; i++)
      {
         SignalBuffer[i]  = iMAOnArray(TaichiBuffer,0,Kijun,0,MODE_LWMA,i);
         SSignalBuffer[i] = iMAOnArray(TaichiBuffer,0,Senkou,0,MODE_LWMA,i);   
         FlatBuffer1[i]   = 0;
         FlatBuffer2[i]   = 0;

         double FlatSE = iATR(NULL,0,20,i)/Point/2.0;
            if(MathAbs(((TaichiBuffer[i]-SignalBuffer[i])+(TaichiBuffer[i]- SSignalBuffer[i])+(SignalBuffer[i]-SSignalBuffer[i]))/3.0)<FlatSE*Point)
            {
               FlatBuffer1[i]=SignalBuffer[i]+FlatSE*Point;
               FlatBuffer2[i]=SignalBuffer[i]-FlatSE*Point;
            }
      }
      return(0);
   }
   
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for (i=limit;i>=0;i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         TaichiBuffer[i]    = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,0,y);
         SignalBuffer[i]    = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,1,y);
         SSignalBuffer[i]   = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,2,y);
         TaichiForBuffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,3,y);
         FlatBuffer1[i]     = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,4,y);
         FlatBuffer2[i]     = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",Tenkan,Kijun,Senkou,5,y);

         //
         //
         //
         //
         //
      
            if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
            if (!Interpolate) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(int k = 1; k < n; k++)
            {
               TaichiBuffer[i+k]    = TaichiBuffer[i]    + (TaichiBuffer[i+n]   - TaichiBuffer[i]   )*k/n;
               TaichiForBuffer[i+k] = TaichiForBuffer[i] + (TaichiForBuffer[i+n]- TaichiForBuffer[i])*k/n;
               SignalBuffer[i+k]    = SignalBuffer[i]    + (SignalBuffer[i+n]   - SignalBuffer[i]   )*k/n;
               SSignalBuffer[i+k]   = SSignalBuffer[i]   + (SSignalBuffer[i+n]  - SSignalBuffer[i]  )*k/n;
               FlatBuffer1[i+k]     = FlatBuffer1[i]     + (FlatBuffer1[i+n]    - FlatBuffer1[i]    )*k/n;
               FlatBuffer2[i+k]     = FlatBuffer2[i]     + (FlatBuffer2[i+n]    - FlatBuffer2[i]    )*k/n;
            }               
   }
   
   //
   //
   //
   //
   //
      
   return(0);
}


//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}