//------------------------------------------------------------------
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"
//------------------------------------------------------------------

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1  PaleVioletRed
#property indicator_width1  2

//
//
//
//
//

extern string TimeFrame       = "Current time frame";
extern int    MaPeriod        = 14;
extern int    MaPrice         = PRICE_CLOSE;
extern int    MaMethod        = MODE_SMA;
extern double MaVerticalShift = 0;
extern int    MaShift         = 0;

double ma[];
bool   returnBars;
int    timeFrame;
string indicatorFileName;

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int init()
{
   SetIndexBuffer(0, ma);
      timeFrame  = stringToTimeFrame(TimeFrame);
      returnBars = (TimeFrame=="returnBars");
      indicatorFileName = WindowExpertName();
         SetIndexShift(0,MaShift*timeFrame/Period());
   return (0);
}
int deinit() { return (0); }

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int start()
{
   double pipMultiplier = 1; 
   int counted_bars = IndicatorCounted();
      if(counted_bars < 0) return(-1);
      if(counted_bars > 0) counted_bars--;
           int limit = MathMin(Bars-counted_bars,Bars-1);
           if (returnBars) { ma[0] = limit+1; return(0); }
           if (Digits==3 || Digits==5) pipMultiplier = 10;
   //
   //
   //
   //
   //
   
   if (timeFrame!=Period()) limit = MathMin(Bars-1,MathMax(limit,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for (int i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         ma[i] = iMA(NULL,timeFrame,MaPeriod,0,MaMethod,MaPrice,y)+MaVerticalShift*pipMultiplier*Point;
         if (y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

            datetime time = iTime(NULL,timeFrame,y);
               for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
               for(int k = 1; k < n; k++)
                  ma[i+k] = ma[i] + (ma[i+n] - ma[i])*k/n;
   }
   return (0);
}

//-------------------------------------------------------------------
//
//-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char = StringGetChar(s, length);
         if((char > 96 && char < 123) || (char > 223 && char < 256))
                     s = StringSetChar(s, length, char - 32);
         else if(char > -33 && char < 0)
                     s = StringSetChar(s, length, char + 224);
   }
   return(s);
}